BlogJava-计算机之路-随笔分类-我的操作系统

Kernel启动进程的实验

小爽 — Mon, 19 Mar 2007 05:04:00 GMT

也就是说，假设 0 --> limit --> FFFF
那么如果一个段是expandupward的，他的offset只能是0到limit，而如果是expanddownward的，offset就是从limit到FFFF，且该栈的增长方向是limit-->FFFF，即，数据在内存中总是从低地址放到高地址

今天受益匪浅.....我塞，如果不是在网络上搜索到的这句话，我自己编写的Kernel进程怎么也调试不好。
今天太高兴了，终于把Kernel的进程机制调整好了！！！截个图，庆祝一下。
不过截图有个错误，就是应该是Process的，而不是Thread，这两个东西有本质区别。

小爽 2007-03-19 13:04 发表评论

我的Kernel实现了中断....

小爽 — Tue, 27 Feb 2007 15:26:00 GMT

今天我把Kernel添加了中断处理的部分。经过DEBUG以后终于可以运行了。值得注意的是，FAULTS返回是返回到当前行。

小爽 2007-02-27 23:26 发表评论

今天对Kernel进行了扩充

小爽 — Mon, 26 Feb 2007 04:54:00 GMT

今天对Kernel进行了扩充，为了过两天实现中断机制。我编写了打印彩色字符的kprint函数和打印Int值的函数。期中有些Bug，不过都修改过了。

小爽 2007-02-26 12:54 发表评论

今天更新了我的操作系统Kernel

小爽 — Thu, 22 Feb 2007 14:56:00 GMT

今天更新了Kernel，编写了一个Kernel的Print函数，void kprint(char *); 好久没有更新了，唉，过年了，事情太多了，没办法，串亲戚，会朋友.......

小爽 2007-02-22 22:56 发表评论

我的KERNEL的树结构列表（学习于渊的）

小爽 — Sat, 03 Feb 2007 15:26:00 GMT

虽然这还不能完全算是自己的，但是总算有了进步啊，呵呵，加油，要设计出自己的操作系统！！

小爽 2007-02-03 23:26 发表评论

没有想到堆栈的问题会这么严重！！

小爽 — Sat, 03 Feb 2007 15:10:00 GMT

今天发现自己的操作系统虽然可以在VMware和VPC下运行，但是在Bochs下会报错！短短的几秒钟使得Bochs产生了几十兆甚至上百兆的输出文件。在文件里面，我发现报错主要是IRET的消息，说堆栈似乎有问题。经过检查代码，我发现了问题所在。应该是mov esp,0x100的一句，写成了mov esp,0100,最后估计是因为堆栈不够造成了Bochs报错。现在总算调节好了，截个图。庆祝一下！

小爽 2007-02-03 23:10 发表评论

今天对Kernel进行了DEBUG，使用了C语言和汇编混合编程

小爽 — Fri, 02 Feb 2007 14:14:00 GMT

虽然从整体上来看好像没有什么变化，但是今天修改了N多个BUG，总算是完成汇编和C语言的混合编程。问题最严重的BUG是ELF文件的ProgramHeader的读取。我没有想到，竟然ELF格式的ProgramHeader有的竟然段长度为0！！这可怎么理解啊，唉，找些书籍看看吧。弄不懂的话影响将来开发Kernel啊....

小爽 2007-02-02 22:14 发表评论

关于C语言中static关键字的一些细节

小爽 — Wed, 31 Jan 2007 12:12:00 GMT

定义了static 该变量就不可以为其他文件所用了,这块内存区域标识为私有,这样可以防止一些内存的错误操作,处于同样的道理,头文件里面是不许出现static的

小爽 2007-01-31 20:12 发表评论

LOADER终于载入KERNEL了！！

小爽 — Wed, 31 Jan 2007 11:20:00 GMT

今天编写了一下午程序，最终完成了LOADER载入KERNEL并把控制权交给了以ELF格式存在于磁盘上的KERNEL.BIN了。值得庆祝的一天，因为以后终于可以使用C和汇编混合编程了，Wow~~~~~~~~截个图，呵呵。

小爽 2007-01-31 19:20 发表评论

今天开始写操作系统初始化Kernel部分

小爽 — Wed, 31 Jan 2007 07:28:00 GMT

今天开始写对ELF格式Kernel载入的程序，ELF文件格式本身并不难，只不过这段需要认真编写程序。下面截个图。

小爽 2007-01-31 15:28 发表评论

Cycar名称修改...

小爽 — Mon, 22 Jan 2007 06:02:00 GMT

看来Cycar要修改名字了，Cycar已经有人用了，虽然不是操作系统。准备修改名称为Cycardy......

小爽 2007-01-22 14:02 发表评论

今天对我的“准操作系统”进行了修改

小爽 — Sun, 21 Jan 2007 08:20:00 GMT

我准备把自己的系统命名为Cycar，名字的由来？来自两个单词，Cyber和Cardinal，分别是数字和非常重要（红衣主教）的意思。希望我的这个系统将来能够越来越powerfull。目前来说，这个不能算是自己的操作系统，因为它缺少很多东西，但是，这些回慢慢扩充的。同时，他目前可以算是按照《自己动手写操作系统》一步一步下来的，没有原创的东西。如果非要给它一个版本号的话，那么它的版本号是 -10.0，因为我还有十分的东西需要学习和领悟，然后慢慢实现自己的操作系统。最终实现0.0.1版本。呵呵呵。截个图。

小爽 2007-01-21 16:20 发表评论

今天的Loader实验总算DEBUG完成

小爽 — Thu, 18 Jan 2007 08:22:00 GMT

今天的程序编写倒不是很长时间，但是DEBUG花了我好长时间，具体前几次崩溃的原因没有找出来，但是最终可以运行了。
截个图片，然后是汇编程序。

org 0x100
[bits 16]
jmp loaderStart

_GRAPH_SEG_OFFSET_ equ 0xb800

_RootEntCnt_ equ 0xe0

BS_OEMName db 'XXXXXXXX'
BPB_BytsPerSec dw 0x200
BPB_SecPerClus db 1
BPB_RsvdSecCnt dw 1
BPB_NumFATs db 2
BPB_RootEntCnt dw _RootEntCnt_
BPB_totSec16 dw 0xb40
BPB_Media db 0xf0
BPB_FATSz16 dw 9
BPB_SecPerTrk dw 0x12
BPB_NumHeads dw 2
BPB_HiddSec dd 0
BPB_totSec32 dd 0
BS_DrvNum db 0
BS_Reserved1 db 0
BS_BootSig db 0x29
BS_VolID dd 0
BS_VolLab db '11111111111'
BS_FileSysType db 'FAT12 '

parameters:
screenPo dd 0
STR_LEN equ 12
bootStr db 'Loading... '
noLoaderStr db 'No Kernel...'
ready db 'Ready '
KernelBase equ 0x8000
KernelOffset equ 0x0
rootEntryNum db _RootEntCnt_
loaderName db 'KERNEL BIN'

loaderStart:
mov ax,cs
mov ds,ax
mov es,ax
mov ss,ax
mov sp,0100
mov ax,_GRAPH_SEG_OFFSET_
mov gs,ax

mov dh,0
call displayStr

xor ah,ah
mov dl,[BS_DrvNum]
int 0x13

mov ax,KernelBase
mov es,ax
mov bx,0
mov ax,19
mov cl,14
call readSector

xor edi,edi

anotherFile:
xor esi,esi
cmp byte [rootEntryNum],0
je noLoader

nextChar:
mov al,byte [es:edi]
cmp byte [ds:loaderName+si],al
jne notThisFile
cmp si,10
je found
inc esi
inc edi
jmp nextChar

notThisFile:
shr edi,5
inc edi
shl edi,5
dec byte [rootEntryNum]
jmp anotherFile

noLoader:
mov dh,1
call displayStr
jmp $

found:
mov dh,2
call displayStr

mov ax,word [es:edi+(0x10)]
mov cl,1

push ax
mov ax,KernelBase
mov es,ax
mov ebx,KernelOffset
pop ax

readEntry:

cmp ax,0xfff
je readEnd
push ax
add ax,19+14-2
call readSector
pop ax

add ebx,512
call getFATEntry

jmp readEntry
readEnd:

jmp toProtectMode

displayStr:
; dh: String index
push cx
push ax
push bx
push esi
push edi
mov cx,STR_LEN
mov edi,dword [screenPo]
mov esi,bootStr
xor eax,eax
mov al,dh
mov bl,STR_LEN
mul bl
add esi,eax
.1:
lodsb
mov [gs:edi],al
inc edi
inc edi
loop .1

mov dword [screenPo],edi
pop edi
pop esi
pop bx
pop ax
pop cx
ret

readSector: ;ax: starting sector cl:number of sectors
; ah 0x2          al:number of sector to read
;      bx: es:bx
; ch:cylinder   cl:start sector
; dh:head num   dl:Drive
push bp
mov bp,sp
push cx
push dx
push ax

mov dl,[BPB_SecPerTrk]
div dl
mov cl,ah
inc cl

mov ch,al
shr ch,1

mov dh,al
and dh,1

mov dl,byte [BS_DrvNum]

.1:
mov ah,2
mov al,byte [bp-2]
int 0x13
jc .1

pop ax
pop dx
pop cx
pop bp
ret

getFATEntry:
FATBaseInMem equ 0x7000
;ax is the entry number
;return ax is the next entry

push es
push bx
push dx
push cx

mov bx,FATBaseInMem
mov es,bx

mov bx,3
mul bx ;dx:ax
mov bx,2
div bx ;dx is the rest
push dx

xor dx,dx
mov bx,[BPB_BytsPerSec]
div bx
mov cl,2
xor bx,bx
add ax,1
call readSector
mov bx,dx; mov byte index

pop dx
xor ax,ax
cmp dx,0
jne oddPart

mov ax,word [es:bx]
and ax,0x0fff

jmp after
oddPart:

mov ax,word [es:bx]
shr ax,4

after:
pop cx
pop dx
pop bx
pop es

ret

toProtectMode:
jmp start

%macro Descriptor 3
dw %2 & 0xffff
dw %1 & 0xffff
db (%1 >> 16) & 0xff
dw ((%2 & 0x0f0000) >> 8) | (%3 & 0xf0ff)
db (%1 >> 24) & 0xff
%endmacro

DummyGDT: Descriptor 0,0,0
CodeGDT: Descriptor 0,0xfffff,1100000010011010b
DataGDT: Descriptor 0,0xfffff,1000000010010010b
ScreenGDT: Descriptor 0xb8000,0xffff,0000000010010010b

GDTPtr dw $-DummyGDT-1
dd 0x9000*0x10+DummyGDT

CodeSelector equ CodeGDT-DummyGDT
DataSelector equ DataGDT-DummyGDT
ScreenSelector equ ScreenGDT-DummyGDT

start:
call killMotor
cli
mov dh,2
call displayStr

lgdt [GDTPtr]

in al,0x92
or al,10b
out 0x92,al

mov eax,cr0
or eax,1
mov cr0,eax

jmp dword CodeSelector:(0x9000*0x10+ProtectMode)

killMotor:
push dx
mov dx,0x3f2
mov al,0

out dx,al
pop dx
ret

[bits 32]
ProtectMode:
mov ax,ScreenSelector
mov gs,ax
xor edi,edi
.again:
inc byte [gs:edi]
jmp .again

小爽 2007-01-18 16:22 发表评论

int 13h 不能将数据读入显存的原因

小爽 — Wed, 17 Jan 2007 05:38:00 GMT

在我认为，读写磁盘的BIOS中断13H是用来向可用内存（内存TYPE为1）中存入数据的。虽然目前对于X86结构的显存机制不是特别的了解，但是显存的TYPE是2，这也就意味着不能够被操作系统任意使用。这样，INT 13H也就不能够直接把磁盘数据转存到显存里面。如果需要把它的数据显示到屏幕上面，可以通过下面的方式：

磁盘-->可用内存-->显存

应该是这样吧，现在我仅仅是感性理解，需要将来看一些深入的书籍来了解。

小爽 2007-01-17 13:38 发表评论

今天把Boot程序DEBUG完成了

小爽 — Tue, 16 Jan 2007 10:40:00 GMT

今天终于把Boot程序DEBUG完成了，下一步是编写Loader进行载入，我把我的Unit3最后一个完成的程序命名成Loader.com并拷贝到磁盘上面，结果发现载入运行正常！！鼓励一下，再接再厉！！

小爽 2007-01-16 18:40 发表评论

开始编写载入程序

小爽 — Tue, 16 Jan 2007 04:00:00 GMT

今天开始编写载入程序Loader了，Loader应该负责载入内核和跳入保护模式，然后把控制权交给内核。内核估计要过一段时间才能编写的，先编写Loader吧。

搞不懂为什么那本书要把内核编译成elf格式的.....有空得看看gcc了

小爽 2007-01-16 12:00 发表评论

对于int 0x13不能载入到显存的确认程序

小爽 — Fri, 12 Jan 2007 02:56:00 GMT

org 0x7c00

mov ah,0
mov dl,0
int 0x13

mov ax,0x7f0
mov es,ax
mov ah,2
mov ch,0
mov dh,0
mov al,1
mov cl,2
mov dl,0
mov ebx,0
int 0x13

mov ax,0xb800
mov gs,ax
jmp 0x7f00

times 510-($-$$) db 0
dw 0xaa55

again:
.1:
inc byte [gs:8]
jmp .1

times 1024-($-$$) db 0

这个程序的执行成功说明有一段的内存地址是不能够被int 0x13访问的。但是具体是为什么需要进一步思考。

小爽 2007-01-12 10:56 发表评论

编写载入程序读磁盘出现的问题

小爽 — Fri, 12 Jan 2007 02:08:00 GMT

mov ah,0
mov dl,0
int 0x13

mov ax,0x7d00; original: mov ax,0xb800
mov es,ax
mov ah,2
mov ch,0
mov dh,0
mov al,1
mov cl,1
mov dl,0
mov ebx,0
int 0x13

mov ah,0x4c
int 0x21

这么短短的程序,在原先把磁盘第一扇区的数据载入到B800：0000从屏幕显示出来却执行完成后B800：0000却没有数据，而如果修改了地址为7d00却可以，这是为什么呢？

小爽 2007-01-12 10:08 发表评论

使用GCC和NASM在Linux下联合编译

小爽 — Wed, 10 Jan 2007 14:06:00 GMT

今天使用nasm和gcc一起编译了一个程序
先使用nasm编译一个asm文件为elf格式，汇编文件里面有全局global的_start和functionC，将来连接的时候用。其中还有extern用来表示外部C语言中的函数。

我的程序的调用结构： _start(ASM)->funB(C)->funC(ASM)
其中 ASM文件中：extern funB、global _start、global funC
C文件中声明：void funC();

函数参数的传递：使用push来传递地址，而不是数值。最后参数的清理需要caller来自己解决。

需要的命令行：

nasm -f elf -o dest.o src.asm

gcc -c -o dest2.o src2.c (-c 的意思是仅仅compile)

ld -s -o final.o dest.o dest1.o

小爽 2007-01-10 22:06 发表评论

关于BIOS中断访问磁盘

小爽 — Wed, 10 Jan 2007 07:33:00 GMT

因为磁盘的前512字节负责启动机器，而512字节如果想完成关于保护模式，载入中断向量，磁盘读写等功能几乎不可能。所以前512字节几乎都用来载入磁盘上特定的一个程序来进行下一步的工作。而载入的工作常常是利用中断0x13来进行的。而由于中断的限制，所以Linux不能引导1024扇区以后的内容。不过当系统引导起来以后，因为重新载入了中断向量，所以原来的int就不能够使用了。而在那时候，操作系统就使用端口来读写磁盘了，就不需要再使用原来的BIOS中断了。

小爽 2007-01-10 15:33 发表评论

想写个自己的操作系统

小爽 — Tue, 09 Jan 2007 15:58:00 GMT

目前研究操作系统，整天使用汇编语言，很想写个自己的操作系统。不要求实用性，只求实现自己多年的梦想。

小爽 2007-01-09 23:58 发表评论

用来理解显示页概念的汇编程序(NASM)

小爽 — Thu, 28 Apr 2005 14:24:00 GMT

;很多书都在说显示页，就是没有人说到底显示页的概念具体是什么的。
;80x86字符显示页有8个。有对应的BIOS中断来切换页的，页与页之间没有直接关系的。
;当程序在多个页中写程序时，可以及时地在各个页中切换。向屏幕写字符并且想要立刻看到，一定要写到当前显示的页中。
;阅读下面的程序需要有引导程序的知识

;下面的程序功能是在8个页中写入不同的字符，最后在各个页中切换。

;******************************************
;Copy Right Xiaoshuang Wang
;B.F.U
;2005
; 转载请保留此部分
;******************************************

org 0x7c00

bootStart:
xor ax,ax
mov ds,ax
mov ss,ax
mov sp,0x7c00
mov bp,sp

; Init the DRIVE
; Boot drive number is stored in DX(lower part)
mov [drive],dl

again:

mov cx,200
againChar:
call putString
loop againChar

mov al,[page]
inc al
mov [page],al
cmp al,0x8
jne again

mov cx,0x9
xor al,al
mov [page],al
check:
mov ah,0x05
int 0x10
xor ah,ah
int 0x16
mov al,[page]
inc al
mov [page],al
loop check

db 0xea
dw 0x0000, 0xffff

data db '012345678'

putString:
mov si,[page]
mov al,[data+si]
mov ah,0x0a
mov bl,0x07
mov bh,[page]
int 0x10
retn

;************************
; Here are the data part
;************************
drive db 0
page db 0

times 510-($-$$) db 0
dw 0xaa55

小爽 2005-04-28 22:24 发表评论

BIOS中断获得磁盘数据是怎么工作的？

小爽 — Thu, 21 Apr 2005 09:47:00 GMT

我用nasm编写了一个Bin文件，利用VMware把这个Bin文件作为一个软盘镜像，实际上，这个“软盘”只有512字节。结果我利用BIOS中断得到的这个“软盘”的数据却是......（如上图）。算下来，大概有1.44M的空间，可实际上只有512字节啊。BIOS中断获得磁盘数据究竟是怎么工作的呢？暂时一个谜......

小爽 2005-04-21 17:47 发表评论

INT 0x10，功能号0x0E（显示一个字符）

小爽 — Thu, 21 Apr 2005 09:27:00 GMT

关于显示一个字符到当前屏幕的INT 0x10，功能0x0E：

              高八位   低八位
              功能      ASCII号
      AX= 0x0E

               页号        前景色
      BX=  0x00？
   （各个页有什么不同？）

小爽 2005-04-21 17:27 发表评论