[分享]封装了个 WSC 脚本组件(ASP 下的 PreparedStatement)

防注入一直是 ASP 的软肋, 我们都知道在 Java 中访问数据库有 PreparedStatement。这在 JSP 中访问数据库时防 SQL 注入提供了很大方便。
在 ASP 中要也有这么个东东就好了。ASP 一般都通过 ADODB 组件访问数据库的，其实 ADODB.Command 就有 Prepared 的功能。早上没事干就封装了一下，做成 WSC 脚本组件的形式。以方便以后的使用。
下面是 Connection.WSC 的代码：（代码以文本形式保存为 Connection.WSC 就可以了）

<?xml version="1.0" encoding="UTF-8"?>
<?component error="0" debug="0" ?>
<component>
  <comment>Alvin(ialvin.cn)</comment>
  <registration description="Connection" progid="ALIB.Connection" version="1.00" remotable="true"
	classid="{46dac711-0b77-43b2-b195-1ee912dcb322}"></registration>
  <public>
	<property name="Count"><get/></property>
	<property name="ActiveConnection"><get/></property>
	<property name="ConnectionString"><get/><put/></property>

<method name="Prepare"><PARAMETER name="sql"/></method>
	<method name="ResetParam"></method>
	<method name="Open"></method>
	<method name="Execute"></method>
	<method name="QueryS"></method>
	<method name="Query"><PARAMETER name="cursorType"/><PARAMETER name="lockType"/></method>
	<method name="OpenRS"><PARAMETER name="rs"/><PARAMETER name="cursorType"/><PARAMETER name="lockType"/></method>
	<method name="EncodeLike"><PARAMETER name="str"/></method>
	<method name="SetNull"></method>
	<method name="SetInt"><PARAMETER name="num"/></method>
	<method name="SetFloat"><PARAMETER name="num"/></method>
	<method name="SetString"><PARAMETER name="str"/></method>
	<method name="SetBinary"><PARAMETER name="bits"/></method>
	<method name="SetBoolean"><PARAMETER name="bln"/></method>
	<method name="SetDateTime"><PARAMETER name="dt"/></method>
  </public>
  <object progid="ADODB.Command" id='oCMD'/>
  <object progid="ADODB.RecordSet" id='oRS'/>
  <implements type="ASP" id="ASP"/>
<script language="VBScript"><![CDATA[
Dim coxn: Set coxn = New Connection
Class Connection
	Private conn, coxnStr, cnt, opened

Public Property Get ActiveConnection()
		Set ActiveConnection = conn
	End Property

Public Property Get Count()
		Count = cnt
	End Property

Public Property Get ConnectionString()
		ConnectionString = coxnStr
	End Property

Public Property Let ConnectionString(ByVal newValue)
		coxnStr = newValue
	End Property

Private Sub Class_Initialize()
		cnt = 0
		opened = False
	End Sub

Public Sub OpenConnection()
		Set conn = CreateObject("ADODB.Connection")
		conn.Open coxnStr
		oCMD.Prepared = True
		oCMD.CommandType = 1
		Set oCMD.ActiveConnection = conn
		opened = True
	End Sub

Public Sub Prepare(ByVal sql)
		If Not opened Then Call OpenConnection()
		Call ResetParam()
		oCMD.CommandText = sql
	End Sub

Public Sub AppendParameter(ByVal value, ByVal dataType)
		Dim param: Set param = oCMD.CreateParameter()
		param.Type = dataType
		param.Value = value
		param.Direction = 1
		Call oCMD.Parameters.Append(param)
	End Sub

Public Function Execute()
		Set Execute = oCMD.Execute()
		cnt = cnt + 1
	End Function

Public Sub OpenRS(ByRef rs, ByVal cursorType, ByVal lockType)
		rs.CursorType = cursorType
		rs.LockType = lockType
		Call rs.Open(oCMD)
		cnt = cnt + 1
	End Sub

Public Sub ResetParam()
		While oCMD.Parameters.Count > 0
			oCMD.Parameters.Delete 0
		Wend
	End Sub

Private Sub Class_Terminate()
		If IsObject(conn) Then
			If conn.State=1 Then Call conn.Close()
			Set conn = Nothing
		End If
	End Sub
End Class

Function get_ConnectionString()
	get_ConnectionString = coxn.ConnectionString
End Function

Function put_ConnectionString(newValue)
	coxn.ConnectionString = newValue
End Function

Function get_ActiveConnection()
	Set get_ConnectionString = coxn.ActiveConnection
End Function

Function get_Count()
	get_Count = coxn.Count
End Function

Function Prepare(ByVal sql)
	Call coxn.Prepare(sql)
End Function

Function SetInt(ByVal num)
	Call coxn.AppendParameter(num, 3)
End Function

Function SetFloat(ByVal num)
	Call coxn.AppendParameter(num, 4)
End Function

Function SetString(ByVal str)
	Call coxn.AppendParameter(str, 8)
End Function

Function SetDateTime(ByVal dt)
	Call coxn.AppendParameter(dt, 135)
End Function

Function SetBoolean(ByVal bln)
	Call coxn.AppendParameter(bln, 11)
End Function

Function SetBinary(ByRef bits)
	Dim param
	Set param = oCMD.CreateParameter("", 205, &H001, -1)
	Call param.AppendChunk(bits)
	Call oCmd.Parameters.Append(param)
	Set param = Nothing
End Function

Function SetNull()
	Call oCMD.Parameters.Append(oCMD.CreateParameter("", 200, &H0001, 1, Null))
End Function

Function Open()
	Call coxn.OpenConnection()
End Function

Function Execute()
	Set Execute = coxn.Execute()
End Function

Function OpenRS(ByRef rs, ByVal cursorType, ByVal lockType)
	Call coxn.OpenRS(rs, cursorType, lockType)
End Function

Function Query(ByVal cursorType, ByVal lockType)
	Set Query = CreateObject("ADODB.RecordSet")
	Call OpenRS(Query, cursorType, lockType)
End Function

Function QueryS()
	QueryS = Null
	Call OpenRS(oRS, 0, 1)
	If oRS.State <> 1 Then Exit Function
	If Not oRS.EOF Then QueryS = oRS.Fields.Item(0).Value
	Call oRS.Close()
End Function

Function ResetParam()
	Call coxn.ResetParam()
End Function

Function EncodeLike(ByVal str)
	Dim regex: Set regex = New RegExp
	regex.Pattern = "[\]\[`\-=\\;',./~!@#$%^&*()_+|{}:""<>?]"
	regex.Global = True
	EncodeLike = regex.Replace(str, "[$+]")
	Set regex = Nothing
End Function
]]></script>
</component>

这是一个脚本，但它却是一个不折不扣的 ActiveX 组件了。
保存成 Connection.WSC 后，右键菜单可以选择注册和注销。

使用方法：

大家如果发现有问题漏洞什么的欢迎留言告知，大家也可以自行完善一下。

posted on 2008-07-05 13:30 林俊海阅读(349) 评论(0) 编辑收藏

新用户注册刷新评论列表


只有注册用户登录后才能发表评论。




网站导航: 博客园 IT新闻知识库 C++博客博问

Blog Stats

News

随笔分类(28)

文章分类(4)

随笔档案(53)

文章档案(4)

相册

相关链接

林俊海的博客