BlogJava-我是void-随笔分类-批处理

查看磁盘剩余空间

void — Sun, 08 Feb 2009 08:53:00 GMT

@echo off

setlocal enabledelayedexpansion

:Main
cls
set /a num2=1024*1024
for %%i in (C D E F) do (
      set num1=0
      set num3_str=
      set num4=
      for /f "tokens=3" %%j in ('dir /-c %%i:\ 2^>nul') do set num1=%%j
      if not "!num1!"=="0" (
          call :loop
          for /f "delims=0 tokens=*" %%k in ("!num3_str!") do set num3_str=%%k
          call :lp2
          echo.
          echo.
          ::echo          %%i 盘剩余空间为 !num3_str! MB
          echo          %%i 盘剩余空间为 !var! GB
      )
          echo.
)
pause
:: goto Main

:loop
:: 求商
set /a num3=%num4%%num1:~0,1%/%num2%
:: 求商序列
set num3_str=%num3_str%%num3%
:: 求余
set /a num4=%num4%%num1:~0,1%%%%num2%
if %num4% equ 0 set num4=
set num1=%num1:~1%
if not "%num1%"=="" goto loop
goto :eof

:lp2
set nchu=%num3_str%
set nbei=1024
set var=
for /l %%a in (1 1 3) do (
       set/a m=nchu/%nbei%,mod=nchu%%%nbei%
       if %%a equ 1 (call set "var=%%var%%%%m%%.") else (call set "var=%%var%%%%m%%")
       call set "nchu=%%mod%%0"
)
::echo %var%
goto :eof

void 2009-02-08 16:53 发表评论

for语句从入门到精通

void — Fri, 21 Nov 2008 09:35:00 GMT

对所有的批处理初学者来说，for的应用是最难理解以及掌握的。本文由浅入深，为大家专门讲解for的用法，希望大家喜欢。
首先应该明确的是,for不是一个简单的命令，它的用法比较复杂,它还可以带四个参数(/L /D /R /F),其中:/L和/F参数是最经常用到的。当然，它本身也可以不带参数，下面我们通过具体的例子来讲解for的运用。

一、不带参数的for：

@echo off

for %%i in (1 2 3 4 5) do echo %%i

pause

将以上代码保存为批处理文件(如何保存?)，然后运行，可以发现屏幕上显示1 2 3 4 5(每字一行)
是不是明白了一些？它的整个运行机制我们可以这样看：for不停的从括号中拿出5个“东西”来（以空格做间隔），并将这5个“东西”依次传给临时变量%%i，同时把这个变量echo出来....

从这个例子我们可以看出，for的基本用法是：
for 变量 in (目标) do 干什么?

变量常用%%i 来表示，当然也可以换成%%j；目标就是待处理的对象集合，比如这里的1 2 3 4 5；这里的干什么的内容为：批处理命令。
【相关习题：】将你的名字用for命令分三行显示出来！！！

二、带参数 /L 的for (这里的参数/L 可以理解为 "list" 的意思，代表一个数列)
先看测试代码：

复制内容到剪贴板

代码:

@echo off

for /l %%i in (1 1 5) do echo %%i

pause

显示结果也为：1 2 3 4 5(每字一行)
它的意思和上面的意思差不多，但是括号中的对象却不需要写成 1 2 3 4 5 的形式了，而是：1 1 5，因为它启用了参数 /L ，就是告诉for，这个括号里的对象是个数列，怎样的数列？就是以 1 开始，步长为1 ，结束值为5的一个等差数列，再举个实例：

复制内容到剪贴板

代码:

::显示 从 10 - 20 的所有偶数：

@echo off

for /l %%i in (10 2 20) do echo %%i

pause

【相关习题：】显示 1~20 间能被5整除的整数

三、带参数 /f 的for（这里的参数/F可以理解为“file”的意思，代码处理对象为文本串）
参考教程：for 命令 /f 参数通俗讲解

四、for的 /D 和/R 参数（这两个参数个人比较少用）
1>/D参数（常用来查询当前目录或者指定目录的文件夹)
基本用法：FOR /D %variable IN (set) DO command [command-parameters]
如：查询F盘根目录下的文件夹

复制内容到剪贴板

代码:

@echo off

for /d %%i in (f:\*) do echo %%i

pause>nul

如果省略括号中的 "f:\"，则会直接查询批处理所在目录的文件夹
假设本批处理文件保存在：F:\test下
运行以下批处理代码，将会查询 F：\test下的文件夹

复制内容到剪贴板

代码:

@echo off

for /d %%i in (*) do echo %%i

pause>nul

2> /r参数
基本用法：FOR /R [[drive:]path] %variable IN (set) DO command [command-parameters]
检查以 [drive:]path 为根的目录树中，所有符合（set）的文件或者文件夹。如果在 /R 后没有指定目录，则使用当前
目录。如果集仅为一个单点(.)字符，则枚举该目录树。
用法示例：
枚举F：盘下所有的文件

复制内容到剪贴板

代码:

@echo off

for /r f:\ %%i in (*) do echo %%i

pause>nul

枚举F：盘下所有的 .bat文件(包括子目录），则：

复制内容到剪贴板

代码:

@echo off

for /r f:\ %%i in (*.bat) do echo %%i

pause>nul

如果省略以上代码中的F:\，则会列举当前目录所有符合（set）的文件
如：列举批处理所在目录的所有批处理文件（包括子目录）

复制内容到剪贴板

代码:

@echo off

for /r %%i in (*.bat) do echo %%i

pause>nul

for 命令 /f 参数通俗讲解

for /f 参数最为复杂,难懂和常用.
在刚学时确实费了我不少脑筋,下面就我个人的理解,给新手们通俗的讲讲,也好让新手少走些弯路.
格式:
::例一:

复制内容到剪贴板

代码:

for /f "skip=1 tokens=1,2* delims= " %%a in (a.txt) do echo %%a %%b %%c

pause

先从引号内的东西讲起,很多新手对这些难以理解,因为 for /? 翻译的简直是一塌糊涂.
skip=
tokens=
delims=
这三项是用的最多的,根据需要.可以不用,可以一起使用,也可以只使用一个或两个.
但是不管使用几个都要用引号将它们扩起来.当然不使用时,自然就不需要引号了.
skip=
for循环文本内容是以行为单位,从上至下进行的,skip=1意识就是跳过文本的第一行,即不循环第一行
那么skip=2 自然就是跳过前两行了,依次类推.........
delims=
先讲这句
delims=后面的字符的意识是,将文本每一行的内容以delims=后面的字符分割成若干列.
假设a.txt某一行的内容是 111,222.333 444/555
我们用下面的语句
::例二:

复制内容到剪贴板

代码:

for /f "tokens=1-5 delims=,./ " %%a in (a.txt) do echo %%a %%b %%c %%d %%e

pause

显示结果是 111 222 333 444 555
解释:
   意识就是把111,222.333 444/555以,./和空格(不分先后)分成了5列.注意代码中/和"后面有个空格,
   使用中要注意空格要放到最后,如"delims=,. /" 这样就不行了.
那如果我们不使用逗号来分割会如何呢?如: "delims=./ "那么就会分割成111,222 333 444 555
看出区别了吗?delims=后面可以是多个字符,可以是空格,也可以什么都没有.
什么都没有代表什么呢?就是不以任何东西为分割符,也是整行的内容了.
因为for默认是以,;和空格作分割符的,
所以一般要取得整行内容通常会用"delims="这样的形式来取消for的默认分割符.
tokens=
tokens=1-5
1-5很好理解就1至5,前面我们用delims=后面的字符为分割符,将文本内容分成了多列,那么你需要的是哪些列呢?
用tokens=可以很好帮你提取到.
还是以例二为例:
通过dilims=,./   将文本分成了111 222 333 444 555 五列.
注意代码中前面有个%%a 这里的%%a就是代表第一列,第二列就是%%b,第三列就是%%c 依此类推.....
那么我们如果把echo %%a %%b %%c %%d %%e 改为 echo %%e %%d %%c %%b %%a 会如何呢?
当然.会显示 555 444 333 222 111
如果是:echo %%b %%d 又会显示什么呢?   不用我说了吧!
若是第一个%%a把它改为%%i也是一样,那么第二列就是%%j...%%k...依此类推....
明白了?就是按英文字母的顺序依此类推的.
这里我们用的是tokens=1-5但是在例一中,我们用的是tokens=1,2* 有什么区别呢?
其实差不多-号代表从几至几而逗号代表单一的,如 tokens=1,5就是代表第一列和第五列,而不是1至5列.
*号代表剩下的所有的列.如:tokens=1,2*代表%%a为第一列,%%b为第二列,%%c代表后面所有的列.
for /f 不但可以循环文本内容还可以循环字符窜,如:
::例三:

复制内容到剪贴板

代码:

for /f "tokens=1-3 delims=,./ " %%a in ("111,222.333 444/555") do echo %%a %%b %%c

pause

只要将()里的字符串用引号扩起来,for就会把它当字符串来循环,而不是文本.

＝＝＝＝＝＝＝＝＝＝＝＝＝＝

＝＝＝＝＝＝＝＝＝＝＝＝＝＝

批处理是一门简单的脚本语言，虽然不能独当一面，但是，若作为工作中的辅助工具，绝对会让大家有随用随写、称心如意的畅快感。

　　和其他语言相比，批处理语言有其先天性的优势：

　　1、系统自带，无需另行安装；
　　2、命令少，语句简洁，上手非常快；
　　3、编写出来的脚本小巧玲珑，随写随用；

　　但是，因为它以命令行方式工作，操作多有不便，在图形界面大行其道的windows世界里，多多少少会让大众望而却步；就算是对命令行有好感的新手，面对微软有如天书的帮助文件，很多人也会败下阵来，因此，论坛里很多会员也发出了编写系统的批处理教程的呼声。

　　编写系统的批处理新手教程，一直是论坛管理层讨论的热点问题，但是，各位管理人员大多都有工作在身，而系统的教程涉及的面是如此之广，面对如此浩大的工程，仅凭一两个人的力量，是难以做好的，因此，本人退而求其次，此次发布的教程，以专题的形式编写，日后人手渐多之后，再考虑组织人力编写全面的教程。

　　之所以选择最难的for，一是觉得for最为强大，是大多数人最希望掌握的；二是若写其他命令教程，如果没有for的基础，展开来讲解会无从下手；三是for也是批处理中最复杂最难掌握的语句，把它攻克了，批处理的学习将会一片坦途。

　　这次的for语句系列教程，打算按照for语句的5种句式逐一展开，在讲解 for /f 的时候，会穿插讲解批处理中一个最为关键、也是新手最容易犯错的概念：变量延迟，大纲如下：

引用:

一前言
二 for语句的基本用法
三 for /f （含变量延迟）
四 for /r
五 for /d
六 for /l

一、前言

　　在批处理中，for是最为强大的命令语句，它的出现，使得解析文本内容、遍历文件路径、数值递增/递减等操作成为可能；配合if、call、goto等流程控制语句，更是可以实现脚本复杂的自动化、智能化操作；合理使用for语句，还能使代码大为简化，免除各位编写大量重复语句之苦。而能否熟练使用for语句，已经成为衡量一个人批处理水平高低最主要的标准。

　　在这个系列教程中，我将通过实际应用中频繁出现的例子，带领大家步入for语句的神奇之门，一步步迈向for语句的魔幻殿堂，使得大家在实际的应用中，能独立写出简洁高效的代码，在批处理的世界里自由驰骋。

　　注意：以下的讲解，都是基于简体中文版Windows XP Pro SP3的操作系统环境。

二、for语句的基本用法[2008.11.9更新]

　　正如色彩缤纷的七彩光芒是由红绿蓝三原色构成的一样，最复杂的for语句，也有其基本形态，它的模样是这样的：
　　在cmd窗口中：

复制内容到剪贴板

代码:

for %I in (command1) do command2

　　在批处理文件中：

复制内容到剪贴板

代码:

for %%I in (command1) do command2

　　之所以要区分cmd窗口和批处理文件两种环境，是因为在这两种环境下，命令语句表现出来的行为虽然基本一样，但是在细节上还是稍有不同，最明显的一个差异就是：在cmd窗口中，for之后的形式变量I必须使用单百分号引用，即%I；而在批处理文件中，引用形式变量I必须使用双百分号，即%%I。为了方便起见，若不是特别强调，以下的讲解都以批处理文件环境为例。

　　我们先来看一下for语句的基本要素都有些什么：

引用:

　　1、for、in和do是for语句的关键字，它们三个缺一不可；
　　2、%%I是for语句中对形式变量的引用，就算它在do后的语句中没有参与语句的执行，也是必须出现的；
　　3、in之后，do之前的括号不能省略；
　　4、command1表示字符串或变量，command2表示字符串、变量或命令语句；

　　现在，你可能已经会写一个简单的for语句了，比如：
[code1]

复制内容到剪贴板

代码:

@echo off

for %%I in (bbs.bathome.cn) do echo %%I

pause

　　保存为批处理文件并执行，将会在弹出的批处理窗口中看到这样的信息：
[result1]

引用:

bbs.bathome.cn
请按任意键继续...

　　很快地，你会觉得这个for语句是如此的简单，简单到你丝毫感受不出它的强大：这个for语句，和我直接用echo语句没什么两样啊！

　　是的，演示代码永远都只是演示而已，就像大多数高级语言的教科书一样，在引导新手学习的时候，基本上都是千篇一律地告诉大家如何编写一个能显示 hello world! 的窗口，从这些演示代码中，你看不到它们具有多少实用性，你只是感到有点好奇：咦，居然弹出了一个窗口？片刻之后，你就会觉得索然无味。

　　那好吧，为了让大家对for更加感兴趣，我们先来分析一下for语句的一些注意事项，之后，再让大家看看更为强大的for语句实例。
　　

引用:

1、for语句的形式变量I，可以换成26个字母中的任意一个，这些字母会区分大小写，也就是说，%%I和%%i会被认为不是同一个变量；形式变量I还可以换成其他的字符，但是，为了不与批处理中的%0～%9这10个形式变量发生冲突，请不要随意把%%I替换为%%0 ～%%9中的任意一个；
　　2、in和do之间的command1表示的字符串或变量可以是一个，也可以是多个，每一个字符串或变量，我们称之为一个元素，每个元素之间，用空格键、跳格键、逗号或等号分隔；
　　3、for语句依次提取command1中的每一个元素，把它的值赋予形式变量I,带到do后的command2中参与命令的执行；并且每次只提取一个元素，然后执行一次do后的命令语句，而无论这个元素是否被带到command2中参与了command2的运行；当执行完一次do后的语句之后，再提取command1中的下一个元素，再执行一次command2，如此循环，直到command1中的所有元素都已经被提取完毕，该for语句才宣告执行结束；

　　其中，第3点是最为关键的，它描述了for语句的执行过程，是for语句的精髓所在，大家一定要牢记这一条，才能深刻理解更为复杂的for流程。

　　有了以上的基础，我们再来看一个例子，这个例子修改了[code1]的部分内容，结果将大不一样：
[code2]

复制内容到剪贴板

代码:

@echo off

for %%I in (bbs,bathome,cn) do echo %%I

pause

　　和[code1]的执行结果[result1]相比，[result2]发生了如下变化：

　　1、显示结果分成了3行（不算最后一行中文提示）；
　　2、每一行都从逗号处被切分；

　　如果把 bbs.bathome.cn 这个字符串中的点号换为空格、跳格或等号，执行结果将和example2的执行结果别无二致。

　　现在，我们来分析一下[code2]代码中for语句的执行过程：

　　首先，for语句以逗号为分隔符，把 bbs,bathome,cn 这个字符串切分成三个元素：bbs、bathome和cn，由此决定了do后的语句将会被执行3次；
　　然后，第一次执行过程是这样的：先把 bbs 这个字符串作为形式变量I的值，带入do后的语句中加以执行，也就是执行 echo %%I 语句，此时的I值为bbs，因此，第一次执行的结果，将会在屏幕上显示bbs这个字符串；第二次执行和第一次执行的过程是一样的，只不过此时I的值已经被替换为command1中的第二个元素了，也就是 bathome 这个字符串；如此循环，当第三次echo执行完毕之后，整条for语句才算执行完毕，此时，将执行下一条语句，也就是pause命令。

　　其实，这个例子只比上一个例子多了一点花样，有趣了那么一点点：一条for语句的执行结果居然被分成了3行！

　　为了让大家见识一下for的真正威力，本人绞尽脑汁，翻帖无数，不得要领，万般无奈之下，只好亮出了尘封在箱底多年的一段代码：检测当前硬盘都有哪些分区^_^
[code3]

复制内容到剪贴板

代码:

@echo off

set str=c d e f g h i j k l m n o p q r s t u v w x y z

echo 当前硬盘的分区有：

for %%i in (%str%) do if exist %%i: echo %%i:

pause

　　这段代码能检测硬盘都有哪些分区，包括U盘和移动硬盘的分区，但是，当光驱中有盘的时候，也会被列出来，这是本代码的一个缺憾，在以后的讲解中，我将向大家讲述如何消除这个瑕疵，敬请关注本系列的后续章节。

　　高级应用：

　　想知道当前目录下都有哪些文件吗？请用下面的代码：

复制内容到剪贴板

代码:

@echo off

for %%i in (*.*) do echo "%%i"

pause

　　想列出当前目录下所有的文本文件吗？请用下面的代码：

复制内容到剪贴板

代码:

@echo off

for %%i in (*.txt) do echo "%%i"

pause

　　想列出只用两个字符作为文件名的文本文件吗？请用下面的代码：

复制内容到剪贴板

代码:

@echo off

for %%i in (??.txt) do echo "%%i"

pause

　　题外话：

　　1、列出当前目录下各种文件的方法，最简单的还是用dir命令，但是，从以上代码中，各位可以加深对for语句执行流程的理解（用到了通配符*和?）；
　　2、注意：以上代码不能列出含有隐藏或系统属性的文件；

　　练习：用for语句建立test1.txt、test2.txt和test3.txt三个文本文件。

　　更全面的练习请看这个帖子：for语句从入门到精通配套练习题

三、文本解析显神威：for /f 用法详解[2008.11.9发表]

　　　　前言

　　for /f 是个十分强大的家伙。
　　如果说，for语句是批处理中最强大的语句的话，那么，for /f 就是精华中的精华。
　　for /f 的强大，和它拥有众多的开关密切相关。因为开关众多，所以用法复杂，本章将分成若干小节，为大家逐一介绍强大的 for /f 语句。

　　　　（一）为解析文本而生：for /f 的基本用法

　　所有的对象，无论是文件、窗体、还是控件，在所有的非机器语言看来，无外乎都是形如"c:\test.txt"、"CWnd"之类的文本信息；而所有的对象，具体的如ini文件中的某条配置信息、注册表中的某个键值、数据库中的某条记录……都只有转化为具有一定格式的文本信息，方可被代码识别、操控。可以说，编程的很大一部分工作，都是在绞尽脑汁想方设法如何提取这些文本信息。
　　而提取文本信息，则是for /f的拿手好戏：读取文件内容；提取某几行字符；截取某个字符片段；对提取到的内容再切分、打乱、杂糅……只要你所能想到的花样，for /f 都会想方设法帮你办到，因为，for /f 就是被设计成专门用于解析文本的。
　　先来看个例子。
　　假如有个文本文件test.txt，内容如下：
[txt1]

引用:

论坛的目标是：不求最大，但求最好，做最实用的批处理论坛。
论坛地址：bbs.bathome.cn。
这里是：新手晋级的福地，高手论剑的天堂。

　　那么，将如下代码保存为test.cmd，并放在test.txt同一目录下运行，将会在屏幕上原样显示test.txt的内容：
[code4]

复制内容到剪贴板

代码:

@echo off

for /f %%i in (test.txt) do echo %%i

pause

　　这段代码，主要是让你树立这样一种观念：读取文本文件的内容，请使用 for /f 语句！

　　进阶话题：for /f 语句是把整个test.txt一次性显示出来的？
　　在这段代码中，虽然执行结果是把test.txt中的所有内容都显示出来了，貌似 for /f 语句是把整个test.txt一次性显示到屏幕上，实际上并非如此。
　　无论for语句做何种变化，它的执行过程仍然遵循基本的for流程：依次处理每个元素，直到所有的元素都被处理为止。只不过在for /f语句中，这里的元素是指文件中的每一行，也就是说，for /f 语句是以行为单位处理文本文件的。这是一条极为重要的规则，在上一章中也强调过它的重要性，希望在接下来的学习过程中，你能时刻牢记这一原则，那么，很多问题将会迎刃而解。以下是验证这一说法的演示代码（在[code4]的基础上添加了&pause语句）：
[code5]

复制内容到剪贴板

代码:

@echo off

for /f %%i in (test.txt) do echo %%i&pause

pause

　　　　（二）切分字符串的利器：delims=

　　也许你对[code4]这段代码不屑一顾：不就是把test.txt的内容显示出来了么？好像用处不大啊。
　　好吧，我们来玩个魔术。
　　还是[txt1]这段文本，把[code4]改造一下：
[code6]

复制内容到剪贴板

代码:

@echo off

for /f "delims=," %%i in (test.txt) do echo %%i

pause

　　再次运行test.cmd，看到什么变化了吗？！
[result2]

复制内容到剪贴板

代码:

论坛的目标是：不求最大

论坛地址：bbs.bathome.cn。

这里是：新手晋级的福地

请按任意键继续...

　　结果，你惊奇地发现，每行第一个逗号之后的所有内容都不见了（如果有不存在逗号的行，则保留原样），也就说，你成功地提取到了每行第一个逗号之前的所有内容！
　　试想一下，这段代码会有什么用呢？
　　如果别人给了你一个软件清单，每行都是"英文软件名（逗号）中文软件名"的格式，而你却只想保留英文名的时候，这段代码将是多么有用啊！再假设，有这么一个IP文件，第一列是数字格式的IP地址，第二列是具体的空间地址，列与列之间用逗号分隔，而你想提取其中数字格式的IP，呵呵，我不说你也知道该怎么办了吧？
　　要是文本内容不是以逗号分隔，而是以其他符号分隔，那么，把"delims=,"的逗号换成相应的符号就可以了。
　　在这里，我们引入了一个新的开关："delims=，"，它的含义是：以逗号作为被处理的字符串的分隔符号。
　　在批处理中，指定分隔符号的方法是：添加一个形如 "delims=符号列表" 的开关，这样，被处理的每行字符串都会被符号列表中罗列出来的符号切分开来。
　　需要注意的是：如果没有指定"delims=符号列表"这个开关，那么，for /f 语句默认以空格键或跳格键作为分隔符号。请把[txt1]中不同位置上的标点符号改为空格或跳格，再运行[code4]试试。

　　进阶话题：如果我要指定的符号不止一个，该怎么办？
　　在上面的讲解中，我提到了指定分隔符号的方法：添加一个形如"delims=符号列表"的开关。不知道你注意到没有，我的说法是"符号列表"而非"符号"，这是大有讲究的，因为，你可以一次性指定多个分隔符号！
　　还是以[txt1]为例，把[code6]再改造一下：
[code7]

复制内容到剪贴板

代码:

@echo off

for /f "delims=.，" %%i in (test.txt) do echo %%i

pause

　　结果显示：
[result3]

复制内容到剪贴板

代码:

论坛的目标是：不求最大

论坛地址：bbs

这里是：新手晋级的福地

请按任意键继续...

　　这样，第一个点号或第一个逗号之前的内容都被提取出来了。
　　[code7]的执行过程是：逐行读取test.txt中的内容，以点号和逗号切分每一行的内容（不存在点号和逗号的行，则不再切分，为了描述的方便，我们把被点号或逗号切分的一个一个的字符串片段，称之为节），然后，for /f 会提取第一节的内容作为最终结果，显示在屏幕上。需要注意的是，在这里，所有行的字符串被切分成了两个以上的节，但是，[code7]的代码只会提取第一节字符串的内容，因为 for /f 语句默认只提取第一节的符串。

　　　　（三）定点提取：tokens=

－－－－－－－－－－－－－
未完成待续，参考： http://bbs.bathome.cn/thread-2189-1-3.html

void 2008-11-21 17:35 发表评论

生成一个SLEEP.EXE的延时命令的bat文件

void — Thu, 24 Jul 2008 06:43:00 GMT

:: Sleep.bat - Sleep/Delay/Wait n seconds
:: Herbert Kleebauer(Germany) - 2005/05/29
:: Modified by Will Sort - 2005/06/02
@echo off
echo q | debug>nul
echo Bj@jzh`0X-`/PPPPPPa(DE(DM(DO(Dh(Ls(Lu(LX(LeZRR]EEEUYRX2Dx=>sleep.com
echo 0DxFP,0Xx.t0P,=XtGsB4o@$?PIyU WwX0GwUY Wv;ovBX2Gv0ExGIuht6>>sleep.com
echo T}{z~~@GwkBG@OEKcUt`~}@MqqBsy?seHB~_Phxr?@zAB`LrPEyoDt@Cj?>>sleep.com
echo pky_jN@QEKpEt@ij?jySjN@REKpEt@jj?jyGjN@SEKkjtlGuNw?p@pjirz>>sleep.com
echo LFvAURQ?OYLTQ@@?~QCoOL~RDU@?aU?@{QOq?@}IKuNWpe~FpeQFwH?Vkk>>sleep.com
echo _GSqoCvH{OjeOSeIQRmA@KnEFB?p??mcjNne~B?M??QhetLBgBPHexh@e=>>sleep.com
echo EsOgwTLbLK?sFU`?LDOD@@K@xO?SUudA?_FKJ@N?KD@?UA??O}HCQOQ??R>>sleep.com
echo _OQOL?CLA?CEU?_FU?UAQ?UBD?LOC?ORO?UOL?UOD?OOI?UgL?LOR@YUO?>>sleep.com
echo dsmSQswDOR[BQAQ?LUA?_L_oUNUScLOOuLOODUO?UOE@OwH?UOQ?DJTSDM>>sleep.com
echo QTqrK@kcmSULkPcLOOuLOOFUO?hwDTqOsTdbnTQrrDsdFTlnBTm`lThKcT>>sleep.com
echo @dmTkRQSoddTT~?K?OCOQp?o??Gds?wOw?PGAtaCHQvNntQv_w?A?it\EH>>sleep.com
echo {zpQpKGk?Jbs?FqokOH{T?jPvP@IQBDFAN?OHROL?Kj??pd~aN?OHROd?G>>sleep.com
echo Q??PGT~B??OC~?ipO?T?~U?p~cUo0x>>sleep.com
sleep.com>sleep.exe
del sleep.com
echo wait 2 seconds:
sleep.exe 2000

-----------------------------------------------------------------------------------------------------------------------

当前路径: %~dp0

时间格式替换:
set new=%time:5=..%, echo %new:~0,5%
(其中time: 为格式, 5为要替换的内容, .. 为要替换成为的内容)

-----------------------------------------------------------------------------------------------------------------------

@echo off

net start mysql

rem 延时两秒

echo q | debug>nul
echo Bj@jzh`0X-`/PPPPPPa(DE(DM(DO(Dh(Ls(Lu(LX(LeZRR]EEEUYRX2Dx=>sleep.com
echo 0DxFP,0Xx.t0P,=XtGsB4o@$?PIyU WwX0GwUY Wv;ovBX2Gv0ExGIuht6>>sleep.com
echo T}{z~~@GwkBG@OEKcUt`~}@MqqBsy?seHB~_Phxr?@zAB`LrPEyoDt@Cj?>>sleep.com
echo pky_jN@QEKpEt@ij?jySjN@REKpEt@jj?jyGjN@SEKkjtlGuNw?p@pjirz>>sleep.com
echo LFvAURQ?OYLTQ@@?~QCoOL~RDU@?aU?@{QOq?@}IKuNWpe~FpeQFwH?Vkk>>sleep.com
echo _GSqoCvH{OjeOSeIQRmA@KnEFB?p??mcjNne~B?M??QhetLBgBPHexh@e=>>sleep.com
echo EsOgwTLbLK?sFU`?LDOD@@K@xO?SUudA?_FKJ@N?KD@?UA??O}HCQOQ??R>>sleep.com
echo _OQOL?CLA?CEU?_FU?UAQ?UBD?LOC?ORO?UOL?UOD?OOI?UgL?LOR@YUO?>>sleep.com
echo dsmSQswDOR[BQAQ?LUA?_L_oUNUScLOOuLOODUO?UOE@OwH?UOQ?DJTSDM>>sleep.com
echo QTqrK@kcmSULkPcLOOuLOOFUO?hwDTqOsTdbnTQrrDsdFTlnBTm`lThKcT>>sleep.com
echo @dmTkRQSoddTT~?K?OCOQp?o??Gds?wOw?PGAtaCHQvNntQv_w?A?it\EH>>sleep.com
echo {zpQpKGk?Jbs?FqokOH{T?jPvP@IQBDFAN?OHROL?Kj??pd~aN?OHROd?G>>sleep.com
echo Q??PGT~B??OC~?ipO?T?~U?p~cUo0x>>sleep.com
sleep.com>sleep.exe
del sleep.com
echo wait 2 seconds:
sleep.exe 2000

rem 初始化

set bkdir=D:\Downloads\Mine\moujie\Backup\
set db=mysql_6
set proj=Proj_eclip

echo ____
echo init
echo ----

set ndate=%date:~4,7%
echo %ndate%

set ntime1=%date:~6,8%
echo %ntime1%

set ntime2=%time:~0,8%
set ntime2=%ntime2::=%
set ntime2=%ntime2: =0%
echo %ntime2%

set sytime=%ntime1%_%ntime2%
echo %sytime%

rem 建立月份文件夹

echo ____
echo path
echo ----

set dbmonthdir=%bkdir%%db%\%ndate%
echo %dbmonthdir%

set projtimedir=%bkdir%%proj%\%ndate%\%sytime%
echo %projtimedir%

if not exist %dbmonthdir% (md %dbmonthdir%)
if not exist %projtimedir% (md %projtimedir%)

set newsqlpath=%dbmonthdir%\%sytime%.sql
echo %newsqlpath%

rem 输出

echo ____
echo cout
echo ----

"D:\Program Files\MySQL\MySQL Server 6.0\bin\mysqldump.exe" -uroot -p123 moujie > %newsqlpath%
xcopy "D:\Program Files\MyEclipse 6.5\workspace\moujie" "%projtimedir%" /S /E /H /Q

rem 析构

echo _______
echo Destroy
echo -------

net stop mysql
del sleep.exe

-----------------------------------------------------------------------------------------------------------------------

@echo off

set destdir=D:\Downloads\Mine\Sys\Mine_Launch

echo ______
echo start?
echo ------
pause

if exist %destdir% (rd %destdir% /S /Q)
if not exist %destdir% (md %destdir%)

xcopy "C:\Documents and Settings\Administrator\Application Data\Microsoft\Internet Explorer\Quick Launch" %destdir% /S /E /H /Q

void 2008-07-24 14:43 发表评论

BlogJava-我是void-随笔分类-批处理

查看磁盘剩余空间

for语句从入门到精通

代码:

代码:

代码:

代码:

代码:

代码:

代码:

for 命令 /f 参数 通俗讲解

代码:

代码:

代码:

引用:

一、前言

二、for语句的基本用法[2008.11.9更新]

代码:

代码:

引用:

代码:

引用:

引用:

代码:

代码:

代码:

代码:

代码:

三、文本解析显神威：for /f 用法详解[2008.11.9发表]

引用:

代码:

代码:

代码:

代码:

代码:

代码:

生成一个SLEEP.EXE的延时命令的bat文件

for 命令 /f 参数通俗讲解