SETLOCAL EnableDelayedExpansion

DEL /F /Q picture.txt 2>NUL

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
:: 原理：
::
:: 一般情况下，有EXIF信息的照片，会有三处时间（当然还有特例），第一处格式为：
::
:: 2001:01:01 02:04:18
::
:: 第二、第三处是在一起的，中间有个NULL值，如下：
::
:: 2001:01:01 02:04:18[NULL]2001:01:01 02:04:18
::
:: 我通过WindowsXP和ACDSee8分析了很多张图片，发现第一处的时间很可能有误，
::
:: 也就是说，WindowsXP和ACDSee8实际使用的应该是第二或第三处的时间，
::
:: 使用第二处的时间。
::
::
:: 注意：
::
:: 1、有些人喜欢把一些秘密藏在图片中，而秘密有可能包含时间，所以，可能有问题，
::
::    不过，这种情况好像很少？
::
:: 2、由于FINDSTR.EXE命令的局限性（并非真正的正则表达式），错误是难免的。
::
::
:: 另外：
::
:: 1、开始我把*.jpeg也列入查找，但发现*.jpe可以搜索到*.jpeg，只好剔掉*.jpeg了
::
:: 2、我讨厌ACDSee8重命名时，把2001-01-01 02-01-19改成2001-01-01 2-1-19，不好看！
::
:: 3、其实我写这个的目的就是修改图片名称为照相时间，剩下的以后写
::
::
:: Author: NeedJava
::
:: Modified: 2007-08-15/2007-08-24/2007-08-25
::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
FOR /R %%a IN ( *.jpg *.jpe *.jfif *.tif ) DO (

   CLS

   ECHO 正在处理〔!%%a!〕

   SET "final=NULL"

   IF "!final!"=="NULL" (

      SET /A times=0

      FOR /F "delims=" %%i IN ( 'FINDSTR.EXE "200 199 201 202" "%%a" 2^>NUL ^| MORE 2^>NUL ^| FINDSTR.EXE /R "\<[1-2][0-9][0-9][0-9][:][0-1][0-9][:][0-3][0-9] [0-2][0-9][:][0-5][0-9][:][0-5][0-9]\>" 2^>NUL' ) DO (

          SET /A times+=1

          IF !times! EQU 2 (

             SET "parse=%%i"

             IF "!parse:~-3,1!"==":" IF "!parse:~-9,1!"==" " (

                SET "parse=!parse:~-19!"

                ECHO Found [!parse!]

                FOR /F "tokens=1,2,3,4,5,6 delims=: " %%A IN ( "!parse!" ) DO (

                    SET "final=%%A-%%B-%%C %%D-%%E-%%F"

                )

             )

          )

      )

   )

   IF "!final!"=="NULL" (

      FOR /F "delims=" %%i IN ( 'FINDSTR.EXE /I "DateTimeOriginal" "%%a" 2^>NUL' ) DO (

          SET "parse=%%i"

          IF /I "!parse:~-24,7!"=="</exif:" IF "!parse:~-30,1!"=="+" (

             SET "parse=!parse:~-49,19!"

             ECHO Found [!parse!]

             FOR /F "tokens=1,2,3,4,5,6 delims=-:T" %%A IN ( "!parse!" ) DO (

                 SET "final=%%A-%%B-%%C %%D-%%E-%%F"

             )

          )

      )

   )

   IF NOT "!final!"=="NULL" (

      ECHO Parse [!final!]

      ECHO [%%~nxa]>>picture.txt

      ECHO !final!>>picture.txt

      ECHO;>>picture.txt

   )

)

GOTO :EOF

@ECHO ON

剩下的就是改名了，由于要防备同名，也就是一秒内拍了两三张这样的情况，所以需要追加数字序列
 

SETLOCAL EnableDelayedExpansion

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
:: 需要区别FAT32和NTFS格式下的回收站
::
:: FAT32回收站结构如下：
::
:: [Recycled]
:: desktop.ini
:: INFO2
::
:: NTFS回收站结构如下：
::
:: [Recycler]
::   [S-1-5-21-1409082233-448539723-725345543-500]
::     desktop.ini
::     INFO2
::   [S-1-5-21-1844237615-2139871995-1417001333-500]
::     desktop.ini
::     INFO2
::   [S-1-5-21-606747145-261478967-839522115-500]
::     desktop.ini
::     INFO2
::
:: 其中：
::
:: desktop.ini用来定义文件夹，告诉系统：你把存我的文件夹变成回收站的样子
::
:: INFO2用来存放当前盘符下删除的文件的原来路径，用8.3短文件名，以及与改名文件对应关系
::
:: 我们就是用的INFO2文件，将里面存放的信息通过两次查找过滤出来
::
:: 重点：
::
:: FIND.EXE ":" "C:\Recycled\INFO2" 2>NUL | FINDSTR.EXE /R "^[A-z]:[\\]" 2>NUL
::
:: 参考：
::
:: http://www.cn-dos.net/forum/viewthread.php?tid=25053&fpage=1&highlight=tokens%3D1%2B&page=1
::
:: 感谢：
::
:: 中国DOS联盟论坛里所有给予我启发的热心人！使我受益匪浅！
::
:: Author: NeedJava
::
:: Modified: 2007.08.13
::
:: BTW: 今晚23时东北方向有英仙座流星雨，我已经调好照相机了
::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
DEL /F /Q deleted.txt 2>NUL

FOR %%a IN ( C D E F G H I J K L M N O P Q R S T U V Y X Y Z ) DO (

    IF EXIST "%%a:\" (

       ECHO 正在搜索〔%%a:〕盘下的回收站……

       FOR /F "delims=" %%i IN ( 'DIR /AH-D /B /S "%%a:\Recycler\INFO2" 2^>NUL' ) DO (

REM        ECHO [%%i] & PAUSE

           CALL :parse %%i

       )

       FOR /F "delims=" %%I IN ( 'DIR /AH-D /B /S "%%a:\Recycled\INFO2" 2^>NUL' ) DO (

REM        ECHO [%%I] & PAUSE

           CALL :parse %%I

       )

    )

)

@ECHO ON

GOTO :EOF

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
:: 重点：
::
:: FIND.EXE ":" "C:\Recycled\INFO2" 2>NUL | FINDSTR.EXE /R "^[A-z]:[\\]" 2>NUL
::
:: 详细解释请关注上面的网站，无奈何版主的叙述，呵呵，本人坐板凳听
::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:parse

ECHO [%1]>>deleted.txt

FOR /F "delims=" %%m IN ( 'FIND.EXE ":" "%1" 2^>NUL ^| FINDSTR.EXE /R "^[A-z]:[\\]" 2^>NUL' ) DO (

    ECHO %%m>>deleted.txt

)

ECHO.>>deleted.txt

后记，鉴于很多病毒喜欢往回收站里面钻，通过查找真正被删除的文件列表，找到对应的删除文件，那么剩下的文件可以看着办了，估计先要用IS杀掉进程

SETLOCAL EnableDelayedExpansion

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
:: 重复文件的手工处理
::
:: 忽略开头为“[”的行，没有用“eol=[”，因为要每隔三次计数器清零，防止相同文件过多打开过多
::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:begin

IF EXIST clone.txt (

   SET /A num=0

   FOR /F "delims=" %%b IN ( clone.txt ) DO (

       SET "file=%%b"

       IF NOT "!file!"=="" (

          IF NOT "!file:~0,1!"=="[" (

             IF !num! GTR 2 (

                SET /A num=0

                ECHO 本组完全相同的文件太多，按任意键继续打开三个……
                ECHO.

                PAUSE>NUL

             )

             IF EXIST "!file!" (

                EXPLORER.EXE /N, /SELECT, "!file!"

                SET /A num=num+1

             )

          ) ELSE (

            IF !num! GTR 0 (

               ECHO 上组完全相同的文件显示完毕。
               ECHO.

            )

            SET /A num=0

            ECHO 按任意键打开下组三个完全相同的文件……
            ECHO.

            PAUSE>NUL

          )

       )

   )

) ELSE (

  GOTO :EOF

)

CLS

ECHO 重新开始……
ECHO.

GOTO begin

@ECHO ON

SETLOCAL EnableDelayedExpansion

ECHO 搜索重复的图片，按任意键继续。
ECHO.

PAUSE>NUL

DEL /F /Q hash.txt 2>NUL
DEL /F /Q sort.txt 2>NUL
DEL /F /Q clone.txt 2>NUL
DEL /F /Q lost.txt 2>NUL

RD /S /Q "Clone\" 2>NUL & MD "Clone\" 2>NUL

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
:: 生成“文件大小|文件路径”，再排序，内容诸如：
::
:: 25329|C:\Documents and Settings\Administrator\桌面\02.jpg
::
:: 把文件大小加上100000000，即100MB，这样方便SORT命令比较大小，那么内容变成如下：
::
:: 100025329|C:\Documents and Settings\Administrator\桌面\02.jpg
::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
CLS

ECHO 正在搜索文件，请稍候……
ECHO.

FOR /R %%a IN ( *.jpg ) DO (

    SET /A size=%%~za+100000000

    ECHO !size!^|%%a>>hash.txt

)

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
:: 根据列表每行前面所列出的文件大小进行排序
::
:: 把文件大小加上100000000，即100MB，这样方便SORT命令比较大小
::
:: 否则SORT会给我们“1、123、1235、2、21、3”这样的顺序
::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
CLS

ECHO 正在排序文件，请稍候……
ECHO.

IF EXIST hash.txt (

   SORT /R hash.txt /O sort.txt 2>NUL

)

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
:: 把大小相同的文件分离成一个个单独的文件，方便后面的相互比较
::
:: 我不认为需要对5MB以上的图片文件进行二进制比较，它们够显眼的了
::
:: 只有大小一样才需要作进一步的二进制比较，否则就是搞笑了
::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
CLS

ECHO 正在分离文件，请稍候……
ECHO.

IF EXIST sort.txt (

   SET "preSize="

   SET "preFile="

   FOR /F "tokens=1,2 delims=|" %%a IN ( sort.txt ) DO (

       SET /A curSize=%%a-100000000

       SET "curFile=%%b"

       IF NOT "!preFile!"=="" IF !preSize! LEQ 5000000 (

          IF !preSize! EQU !curSize! (

             IF /I NOT "!always!"=="true" (

                ECHO !preSize!^|!preFile!>"Clone\!preSize!.vab"

                SET "always=true"

             )

             ECHO !curSize!^|!curFile!>>"Clone\!preSize!.vab"

          ) ELSE (

            SET "always=false"

          )

       )

       SET /A preSize=!curSize!

       SET "preFile=!curFile!"

   )

)

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
:: 微软一些DOS命令的搞笑BUG：
::
:: FC：名称的字数超过185个的文件夹不予理会
::
:: DIR：把路径中的一些Unicode码（如30FB）用半角问号“?”代替，记事本也如此
::
:: FOR /R：不但把Unicode码（如30FB）用半角问号“?”代替，还会删除路径中的“!”和“^”
::
:: 以上这些微软BUG，使这个批处理也有了BUG：路径中不能有“!”、“^”和一些Unicode码
::
::
:: FC命令返回代码含义：
::
:: 0   完全相同
::
:: 1   不完全同
::
:: 2   缺少文件
::
::
:: FIND命令返回代码含义：
::
:: 0   找到字符串
::
:: 1   没有找到字符串
::
::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:reload

IF EXIST "Clone\" (

   FOR /R "Clone\" %%a IN ( *.vab ) DO (

       SET "list=Clone\%%~nxa"

       SET /A num=1

       GOTO cycle

   )

)

GOTO delete

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
:: 原理：
::
:: 假设有DATA[A B C D B A A]这个7位数组需要自身比较，按照正常的方法，如下：
::
:: for( int i=0; i<n-1; i++ )
::    {
::      for( int j=i+1; j<n; j++ )
::         {
::           compare DATA[i] DATA[j]...
::         }
::    }
::
:: 需要比较N*(N-1)/2次，即7*(7-1)/2=21次，如下：
::
:: [A B]、[A C]、[A D]、[A B]、[A A]、[A A]
::
:: [B C]、[B D]、[B B]、[B A]、[B A]
::
:: [C D]、[C B]、[C A]、[C A]
::
:: [D B]、[D A]、[D A]
::
:: [B A]、[B A]
::
:: [A A]
::
:: 但是从上面的列表可以发现，有些已经被确定和某个数相同的数，如[A]和[B]两类，
::
:: 在后面依然和别的数继续比较，这是不科学的，应该在找到相同类后，删除它们。
::
:: 也就是说，一旦找到相同的类，就把它们剔除出循环，那么循环应该如下：
::
:: A B C D B A A
::
:: 第一次循环找出所有相同的[A]后，待比较列表动态变为：
::
:: B C D B
::
:: 第二次循环找出所有相同的[B]后，待比较列表动态变为：
::
:: C D
::
:: 如上，那么比较为：
::
:: [A B]、[A C]、[A D]、[A B]、[A A]、[A A]
::
:: [B C]、[B D]、[B B]、[BXA]、[BXA]
::
:: [C D]、[CXB]、[CXA]、[CXA]
::
:: [DXB]、[DXA]、[DXA]
::
:: [BXA]、[BXA]
::
:: [AXA]
::
:: 中间有X的表示已被缩减的，即最终比较为：
::
:: [A B]、[A C]、[A D]、[A B]、[A A]、[A A]
::
:: [B C]、[B D]、[B B]
::
:: [C D]
::
:: 整个批处理原理：
::
:: 1、FOR命令通过%%~za生成零散的，每列开头为文件大小的文件列表hash.txt，如：
::
::    100017000|E:\123.jpg
::    100017000|E:\345.jpg
::    100056732|E:\ffff.jpg
::    100017000|E:\OK\123.jpg
::    100056732|E:\OK\ffff.jpg
::    100012345|E:\OK\gag.jpg
::
:: 2、SORT命令将hash.txt从大到小（当然也可以从小到大）排序成sort.txt，如：
::
::    100056732|E:\ffff.jpg
::    100056732|E:\OK\ffff.jpg
::    100017000|E:\123.jpg
::    100017000|E:\345.jpg
::    100017000|E:\OK\123.jpg
::    100012345|E:\OK\gag.jpg
::
:: 3、分析sort.txt列表文件，如果有两行以上大小相同的纪录，分离到同一个新列表文件：
::
::    文件名：Clone\56732.vab，内容如下：
::    100056732|E:\ffff.jpg
::    100056732|E:\OK\ffff.jpg
::
::    文件名：Clone\17000.vab，内容如下：
::    100017000|E:\123.jpg
::    100017000|E:\345.jpg
::    100017000|E:\OK\123.jpg
::
:: 4、通过双层嵌套FOR命令，进行比较，相同的纪录进clone.txt，也就是最终文件；
::
::    不相同的则纪录进新的文件comparedN.vab，此处N为数字1、2、3、4，如果不删除，
::
::    可以看到动态的待比较列表，用于调试。
::
::    一旦生成了comparedN.vab文件，就表示有未比较的文件，则将待比较列表list设成
::
::    最新的comparedN.vab文件，并且跳转到双层嵌套FOR命令开头cycle，重新循环。
::
::    一旦待比较列表list消失，则表明此类大小的文件比较完毕，跳转到reload，分析下
::
::    一个大小的文件列表。
::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:cycle

REM TYPE !list! & PAUSE

IF EXIST !list! (

   FOR /F "tokens=1,2 delims=|" %%M IN ( !list! ) DO (

       SET "found=false"

REM    :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
REM    ::
REM    :: 我们分析的文件内容是用“|”分隔的，如下：
REM    ::
REM    :: 56732|E:\ffff.jpg
REM    ::
REM    :: tokens=1,2 delims=|会把内容分割成两部分，即56732和E:\ffff.jpg
REM    ::
REM    :: 第一个部分用变量%%m表示，也就是文件大小56732
REM    ::
REM    :: 第二个部分用变量%%n表示，也就是文件完整的路径E:\ffff.jpg
REM    ::
REM    :: skip=1表示跳过一行，用来防止自身比较。当然为了稳妥，下面还是用了判断
REM    ::
REM    :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
       FOR /F "skip=1 tokens=1,2 delims=|" %%m IN ( !list! ) DO (

REM        :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
REM        ::
REM        :: 必须是大小相同的文件才能比较。不是必要，但稳妥起见还是判断一下
REM        ::
REM        :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
           IF /I "%%M"=="%%m" (

REM           ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
REM           ::
REM           :: 不能自己跟自己比较。虽然上面用skip=1跳过，但稳妥起见还是判断一下
REM           ::
REM           ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
              IF /I NOT "%%N"=="%%n" (

                 CLS

                 ECHO 正在比较以下%%M字节的两个文件：
                 ECHO %%N
                 ECHO %%n
                 ECHO.

REM              PAUSE

REM              :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
REM              ::
REM              :: 根据FC命令用二进制比较，所返回的错误码来判断两个文件是否相同
REM              ::
REM              :: Windows 2000下FC命令有问题，所以Windows 2000不能使用此批处理
REM              ::
REM              :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
                 FC.EXE /B "%%N" "%%n">NUL 2>NUL

REM              :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
REM              ::
REM              :: 两个文件比较后完全相同，FC命令会返回0
REM              ::
REM              :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
                 IF !ERRORLEVEL! EQU 0 (

                    ECHO 两个文件完全相同！
                    ECHO.

REM                 PAUSE

REM                 ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
REM                 ::
REM                 :: 如果!found!为true，就表示在比较循环中，遇到了第一次相同
REM                 ::
REM                 :: 用于在找到的列表clone.txt中写入新的标题
REM                 ::
REM                 ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
                    IF /I NOT "!found!"=="true" (

                       ECHO [%%M Bytes]>>clone.txt
                       ECHO %%N>>clone.txt

                       SET "found=true"

                    )

                    ECHO %%n>>clone.txt

                 )

REM              :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
REM              ::
REM              :: 两个文件比较后不相同，FC命令会返回1
REM              ::
REM              :: 把不相同的文件写入下一个待比较列表
REM              ::
REM              :: 这个列表将取代现有列表用于下次循环
REM              ::
REM              :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
                 IF !ERRORLEVEL! EQU 1 (

REM                 ECHO %%n & ECHO. & PAUSE

                    ECHO %%m^|%%n>>"compared!num!.vab"

                 )

REM              :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
REM              ::
REM              :: 找不到相应的文件时，FC命令会返回2
REM              ::
REM              :: 由于FOR /R命令得出的路径，会删除路径中的“!”和“^”，
REM              ::
REM              :: 这会导致虽然待比较列表有路径（错误的），然而FC命令却找不到
REM              ::
REM              :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
                 IF !ERRORLEVEL! EQU 2 (

REM                 ECHO %%n & ECHO. & PAUSE

                    IF NOT EXIST "%%N" (

                       ECHO %%M^|%%N>>lost.txt

                    )

                    IF NOT EXIST "%%n" (

                       ECHO %%m^|%%n>>lost.txt

                    )

                 )

              )

           )

       )

REM    :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
REM    ::
REM    :: 如果!found!为true，就表示在这次循环中找到了相同文件
REM    ::
REM    :: 那么针对这次循环的结束，在找到的列表clone.txt中追加一个空行，用来分隔
REM    ::
REM    :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
       IF /I "!found!"=="true" (

          ECHO.>>clone.txt

       )

REM    :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
REM    ::
REM    :: 删除现有的待比较列表，必须删除，否则会陷入死循环
REM    ::
REM    :: 这也是跳出循环的判断条件，very important!
REM    ::
REM    :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
       DEL /F /Q "!list!" 2>NUL

REM    :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
REM    ::
REM    :: 如果刚才的循环，有一些文件不相同，就会存在新的待比较列表
REM    ::
REM    :: 我们把它设为新的待比较列表，准备跳转到循环开头，重新循环
REM    ::
REM    :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
       IF EXIST "compared!num!.vab" (

          SET "list=compared!num!.vab"

          SET /A num+=1

       ) ELSE (

         GOTO reload

       )

       GOTO cycle

   )

)

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
:: 删除用过的文件
::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:delete

DEL /F /Q hash.txt 2>NUL
DEL /F /Q sort.txt 2>NUL

RD /S /Q "Clone\" 2>NUL

IF EXIST clone.txt %SystemRoot%\NOTEPAD.EXE clone.txt

@ECHO ON

一，如何得到regini.exe

在Windows XP安装光盘中（其他版本的自己试试），找到I386目录下的regini.ex_文件，用expand.exe命令提取出regini.exe，命令如下：

"%SystemRoot%\System32\EXPAND.EXE" "\\?\CDROM0\I386\REGINI.EX_" "C:\regini.exe"

然后从C盘下将生成的regini.exe文件复制到你需要的地方。

建议：不要从非信任的网站下载regini.exe。

二、简单举例

先打开regedit.exe，以便观看每步产生的变化，将如下内容复制到记事本中，保存为example01.txt、example02.txt文件，然后用如下命令：

REGINI.EXE example01.txt

REGINI.EXE example02.txt

::::::: example01.txt :::::::::: 不要复制我，我是分割线开始 ::::::::::::::::::::

HKEY_CURRENT_USER\example0

HKEY_CURRENT_USER\example0
"example1" = REG_DWORD 1

HKEY_CURRENT_USER\example0
"example2" = REG_SZ "This is an example!"

HKEY_CURRENT_USER\example0
"example3" = REG_MULTI_SZ "This is the first line!" "This is the second line!" "This is the third line!"

HKEY_CURRENT_USER\example0
"example4" = REG_EXPAND_SZ "This is an example! This is an example! This is an example! This is an example! This is an example!"

::::::: example01.txt :::::::::: 不要复制我，我是分割线结束 ::::::::::::::::::::

::::::: example02.txt :::::::::: 不要复制我，我是分割线开始 ::::::::::::::::::::

HKEY_CURRENT_USER\example0 [2 8 19]

::::::: example02.txt :::::::::: 不要复制我，我是分割线结束 ::::::::::::::::::::

修改第一个脚本，再运行试试：

REGINI.EXE example01.txt

没反应，看来已经起作用了，键值变成只读的了！

三、权限代码表

 1  - Administrators 完全访问
 2  - Administrators 读取访问
 3  - Administrators 读取、写入访问
 4  - Administrators 读取、写入、删除访问

 5  - Creator 完全访问
 6  - Creator 读取、写入访问

 7  - everyone 完全访问
 8  - everyone 读取访问
 9  - everyone 读取、写入访问
 10 - everyone 读取、写入、删除访问

 11 - Power Users 完全访问
 12 - Power Users 读取、写入访问
 13 - Power Users 读取、写入、删除访问

 14 - System Operators 完全访问
 15 - System Operators 读取、写入访问
 16 - System Operators 读取、写入、删除访问

 17 - System 完全访问
 18 - System 读取、写入访问
 19 - System 读取访问

 20 - Administrators 读取、写入、执行访问

 21 - Interactive User 完全访问
 22 - Interactive User 读取、写入访问
 23 - Interactive User 读取、写入、删除访问

四、运用在哪里

装好系统、杀毒软件后，删除一些服务键、修改一些自启动键、文件关联键的权限等等。但是话又说回来了，

既然我们可以轻松的修改权限，那么病毒也可以修改回去，防范的方法是转移regini.exe文件，再利用注册表监测软件。

将某个注册表监测软件改个名称，最好再加个壳（不是防杀毒软件，而是防病毒恶意终止），加在服务中，一旦有修改就报警。

五、英文帮助

这部分是从网站找的，作者不详，仅供参考：

Usage: REGINI [-m machinename | -h hivefile hiveroot | -w Win95 Directory] [-i n] [-o outputWidth] [-b] textFiles...

-m specifies a remote windows NT machine whose registry is to be manipulated.

-h specifies a specify local hive to manipulate.

-w specifies the paths to a windows 95 system.dat and user.dat files

-i n specifies the display indentation multiple. Default is 4

-o outputWidth specifies how wide the output is to be. By default the outputWidth is set to
   the width of the console window if standard output has not been redirected to a file.
   In the latter case, an outputWidth of 240 is used.

-b specifies that REGINI should be backward compatible with older versions of REGINI that
   did not strictly enforce line continuations and quoted strings Specifically, REG_BINARY,
   REG_RESOURCE_LIST and REG_RESOURCE_REQUIREMENTS_LIST data types did not need line
   continuations after the first number that gave the size of the data.
   It just kept looking on following lines until it found enough data values to equal the
   data length or hit invalid input. Quoted strings were only allowed in REG_MULTI_SZ.
   They could not be specified around key or value names, or around values for REG_SZ or
   REG_EXPAND_SZ Finally, the old REGINI did not support the semicolon as an end of line
   comment character.

textFiles is one or more ANSI or Unicode text files with registry data.

The easiest way to understand the format of the input textFile is to use the REGDMP
command with no arguments to dump the current contents of your NT Registry to standard
out. Redirect standard out to a file and this file is acceptable as input to REGINI

Some general rules are:
Semicolon character is an end-of-line comment character, provided it is the first
non-blank character on a line

Backslash character is a line continuation character. All characters from the backslash
up to but not including the first non-blank character of the next line are ignored.
If there is more than one space before the line continuation character, it is replaced
by a single space.

Indentation is used to indicate the tree structure of registry keys. The REGDMP program
uses indentation in multiples of 4. You may use hard tab characters for indentation,
but embedded hard tab characters are converted to a single space regardless of their
position.

Values should come before child keys, as they are associated with the previous key at
or above the value's indentation level.

For key names, leading and trailing space characters are ignored and not included in
the key name, unless the key name is surrounded by quotes. Imbedded spaces are part of
a key name.

Key names can be followed by an Access Control List (ACL) which is a series of decimal
numbers, separated by spaces, bracketed by a square brackets (e.g. [8 4 17]).
The valid numbers and their meanings are:

1  - Administrators Full Access
2  - Administrators Read Access
3  - Administrators Read and Write Access
4  - Administrators Read, Write and Delete Access
5  - Creator Full Access
6  - Creator Read and Write Access
7  - World Full Access
8  - World Read Access
9  - World Read and Write Access
10 - World Read, Write and Delete Access
11 - Power Users Full Access
12 - Power Users Read and Write Access
13 - Power Users Read, Write and Delete Access
14 - System Operators Full Access
15 - System Operators Read and Write Access
16 - System Operators Read, Write and Delete Access
17 - System Full Access
18 - System Read and Write Access
19 - System Read Access
20 - Administrators Read, Write and Execute Access
21 - Interactive User Full Access
22 - Interactive User Read and Write Access
23 - Interactive User Read, Write and Delete Access

If there is an equal sign on the same line as a left square bracket then the equal
sign takes precedence, and the line is treated as a registry value. If the text
between the square brackets is the string DELETE with no spaces, then REGINI will
delete the key and any values and keys under it.

For registry values, the syntax is:

value Name = type data

Leading spaces, spaces on either side of the equal sign and spaces between the type
keyword and data are ignored, unless the value name is surrounded by quotes. If the
text to the right of the equal sign is the string DELETE, then REGINI will delete the
value.

The value name may be left off or be specified by an at-sign character which is the
same thing, namely the empty value name. So the following two lines are identical:

= type data
@ = type data

This syntax means that you can't create a value with leading or trailing spaces,
an equal sign or an at-sign in the value name, unless you put the name in quotes.

Valid value types and format of data that follows are:

REG_SZ text
REG_EXPAND_SZ text
REG_MULTI_SZ "string1" "string2" ...
REG_DATE mm/dd/yyyy HH:MM DayOfWeek
REG_DWORD numberDWORD
REG_BINARY numberOfBytes numberDWORD(s)...
REG_NONE (same format as REG_BINARY)
REG_RESOURCE_LIST (same format as REG_BINARY)
REG_RESOURCE_REQUIREMENTS (same format as REG_BINARY)
REG_RESOURCE_REQUIREMENTS_LIST (same format as REG_BINARY)
REG_FULL_RESOURCE_DESCRIPTOR (same format as REG_BINARY)
REG_QWORD numberQWORD
REG_MULTISZ_FILE fileName
REG_BINARYFILE fileName

If no value type is specified, default is REG_SZ

For REG_SZ and REG_EXPAND_SZ, if you want leading or trailing spaces in the value
text, surround the text with quotes. The value text can contain any number of
imbedded quotes, and REGINI will ignore them, as it only looks at the first and
last character for quote characters.

For REG_MULTI_SZ, each component string is surrounded by quotes. If you want an
imbedded quote character, then double quote it, as in string2 above.

For REG_BINARY, the value data consists of one or more numbers. The default base
for numbers is decimal.
Hexidecimal may be specified by using 0x prefix. The first number is the number
of data bytes, excluding the first number. After the first number must come enough
numbers to fill the value.
Each number represents one DWORD or 4 bytes. So if the first number was 0x5 you
would need two more numbers after that to fill the 5 bytes. The high order 3 bytes
of the second DWORD would be ignored.

Whenever specifying a registry path, either on the command line or in an input file,
the following prefix strings can be used:

HKEY_LOCAL_MACHINE
HKEY_USERS
HKEY_CURRENT_USER
USER:

Each of these strings can stand alone as the key name or be followed a backslash
and a subkey path. 
 

SETLOCAL EnableDelayedExpansion

ECHO 搜索重复的图片，按任意键继续。

PAUSE>NUL

DEL /F /Q list.txt 2>NUL

DEL /F /Q sorted.txt 2>NUL

DEL /F /Q clone.txt 2>NUL


::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
:: 生成“文件大小|文件路径”，再排序，内容诸如：
::
:: 25329|C:\Documents and Settings\Administrator\桌面\02.jpg
::
:: 我把文件大小加上100000000，即100MB，这样方便SORT命令比较大小，那么内容变成如下：
::
:: 100025329|C:\Documents and Settings\Administrator\桌面\02.jpg
::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
FOR /R %%a IN ( *.jpg ) DO SET /A size=%%~za+100000000 & ECHO !size!^|%%a>>list.txt

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
:: 根据列表每行前面所列出的文件大小进行排序
::
:: 我把文件大小加上100000000，即100MB，这样方便SORT命令比较大小
::
:: 否则SORT会给我“1、123、1235、2、21、3”这样的顺序
::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
SORT /R list.txt /O sorted.txt 2>NUL

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
:: 我不认为需要对5MB以上的图片文件进行二进制比较，它们够显眼的了
::
:: 只有大小一样才需要作进一步的二进制比较，否则就是搞笑了
::
::
:: FC搞笑：名称字数超过185个的文件夹不予理会
::
:: DIR搞笑：会把路径中的一些Unicode码（如30FB）用半角问号“?”代替，记事本也如此
::
:: FOR /R搞笑：不但会把Unicode码（如30FB）用半角问号“?”代替，还会把路径中的“!”、“^”删除
::
:: 以上这些微软的搞笑BUG，使得我的这个批处理也跟着有了BUG：路径中不能有“!”、“^”和一些Unicode码
::
::
:: FC命令返回代码含义：
::
:: 0   完全相同
::
:: 1   不完全同
::
:: 2   缺少文件
::
::
:: FIND命令返回代码含义：
::
:: 0   找到字符串
::
:: 1   没有找到字符串
::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
SET preSize=

SET preFile=

FOR /F "tokens=1,2 delims=|" %%a IN ( sorted.txt ) DO (

    SET /A curSize=%%a-100000000

    SET curFile=%%b

    ECHO ========================================================================
    ECHO.
    ECHO 上个文件大小：!preSize!
    ECHO.
    ECHO 当前文件大小：!curSize!
    ECHO.
    ECHO 上个文件路径：!preFile!
    ECHO.
    ECHO 当前文件路径：!curFile!
    ECHO.

    IF NOT "!preFile!"=="" IF !preSize! LEQ 5000000 (

       IF !preSize! EQU !curSize! (

          FC.EXE /B "!preFile!" "!curFile!">NUL

          IF !ERRORLEVEL! EQU 0 (

             ECHO 两个文件完全相同！
             ECHO.

             IF /I NOT "!always!"=="true" (

                ECHO.>>clone.txt

                ECHO !preSize!字节>>clone.txt

                ECHO !preFile!>>clone.txt

                SET always=true

             )

             ECHO !curFile!>>clone.txt

          )

       ) ELSE (

         SET always=false

       )

    )

    SET /A preSize=!curSize!

    SET preFile=!curFile!

)

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
:: 删除用过的文件等结尾工作
::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
DEL /F /Q list.txt 2>NUL

DEL /F /Q sorted.txt 2>NUL

@ECHO ON

最近要在Win2000下工作，发现Win2000（没打SP4）提供的FC.EXE命令有问题，不论是在Shell下还是在批处理，一些大小一样的图片，比较的结果都是让%ERRORLEVEL%为0，也就是相同，大家有兴趣可以试试下面两个文件，注意，把jpg改成gif的。





由于上述比较只是假设同种文件的复本，没有考虑同样大小文件的干扰，按习惯，应该一一比较，如〔1、2、3、4〕，需要比较〔1、2〕、〔1、3〕、〔1、4〕、〔2、3〕、〔2、4〕、〔3、4〕这几组，如下：

假设相同文件有n个，理想FOR命令如下：

for( int i=1; i<n; i++ )
   {
     for( int j=i+1; j<=n; j++ )
        {
          compare i and j...
        )
   }

但是FOR命令的局限，很难做到，所以自己也在考虑更好的办法，如下是第二次改进：

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
:: Name: 搜索重复图片（或其他任意类型、大小的文件，对0字节的也比较）
::
:: Author: NeedJava
::
:: Modified: 2007-07-30
::
:: 注意：你可以在任何地方使用此批处理，但必须保持文件作者及注释部分的完整
::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
@ECHO OFF

SETLOCAL EnableDelayedExpansion

ECHO 搜索重复的图片，按任意键继续。
ECHO.

PAUSE>NUL

DEL /F /Q hash.txt 2>NUL
DEL /F /Q sort.txt 2>NUL
DEL /F /Q clone.txt 2>NUL
DEL /F /Q lost.txt 2>NUL

RD /S /Q "Clone\" 2>NUL & MD "Clone\" 2>NUL

ECHO 搜索可用的〔JRE〕路径，按任意键继续。

PAUSE>NUL

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: 设置初始变量
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
SET FileName=预防Autorun病毒

SET FilePath=%ProgramFiles%\\%FileName%.bat

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: 如果原来有BAT文件就先取消所有属性，方便下面的修改
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
IF EXIST "%FilePath%" ATTRIB -S -H -A -R "%FilePath%"

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: 生成BAT文件并存放到指定地点
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: 先删除带路人AUTORUN.INF，注意防止AUTORUN.INF是文件夹>"%FilePath%"
ECHO @IF NOT EXIST AUTORUN.INF\ ATTRIB -S -H -A -R AUTORUN.INF>>"%FilePath%"
ECHO @DEL /F /Q AUTORUN.INF>>"%FilePath%"

ECHO.>>"%FilePath%"
ECHO.>>"%FilePath%"

ECHO :: 设置初始变量>>"%FilePath%"
ECHO @SET FileType=EXE,COM,PIF,LNK,386,VXD,BIN,BAT,CMD,JS,JSE,VBE,VBS,WSF,WSH,HTA,HTT,CHM,HLP,EML,FND,INF,INI,REG,KEY,MSC,MSI,SCF,SCR,SYS>>"%FilePath%"

ECHO.>>"%FilePath%"
ECHO.>>"%FilePath%"

ECHO :: 将隐藏的危险文件显示出来>>"%FilePath%"
ECHO @FOR %%%%a IN ( %%FileType%% ) DO @ATTRIB -S -H -A -R *.%%%%a 2^>NUL>>"%FilePath%"

ECHO.>>"%FilePath%"
ECHO.>>"%FilePath%"

ECHO @ECHO.>>"%FilePath%"
ECHO @ECHO 当前根目录下所有危险文件已经显示，该杀该剐由你处理。>>"%FilePath%"
ECHO @ECHO.>>"%FilePath%"
ECHO @ECHO 记住，千万别双击！用拖选的方式选择要删除的危险文件。>>"%FilePath%"
ECHO @ECHO.>>"%FilePath%"

ECHO.>>"%FilePath%"
ECHO.>>"%FilePath%"

ECHO @PAUSE>>"%FilePath%"

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: 将BAT文件设置系统、存档、只读属性
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
IF EXIST "%FilePath%" ATTRIB +S +A +R "%FilePath%"

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: 生成注册表文件，并且追加进注册表中
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO Windows Registry Editor Version 5.00>AddRegister.reg

ECHO.>>AddRegister.reg

ECHO [-HKEY_CLASSES_ROOT\Drive\Shell\%FileName%]>>AddRegister.reg

ECHO.>>AddRegister.reg

ECHO [HKEY_CLASSES_ROOT\Drive\Shell\%FileName%\Command]>>AddRegister.reg
ECHO @="%FilePath%">>AddRegister.reg

REGEDIT /S AddRegister.reg

DEL /F /Q AddRegister.reg

ENDLOCAL

后记：

现在关于U盘病毒的防止有很多种，按Shift，或在组策略中禁止自动运行。

开始想用FINDSTR.EXE分析Autorun.inf文件，然后根据找到的路径直接删除病毒，但是限制条件怪多的，如真假路径，双执行文件，隐藏目录，想想还是预防为主，顺便鄙视一下Micro$oft！

 

ECHO 将要处理保存的网页文件！按任意键继续。

PAUSE>NUL

DIR /AD /B /S "*.files" 2>NUL | SORT /R >list.txt 2>NUL

FOR /F "delims=" %%a IN ( list.txt ) DO (

    ECHO ========================================================================
    ECHO.
    ECHO 正在处理文件夹〔%%a〕
    ECHO.

    FOR /F "delims=" %%b IN ( 'DIR /B /ON /S "%%a\" 2^>NUL' ) DO (

        ECHO 正在处理文件〔%%b〕

        IF /I NOT "%%~xb"==".jpg" IF /I NOT "%%~xb"==".jpeg" IF /I NOT "%%~xb"==".png" IF /I NOT "%%~xb"==".bmp" DEL /F /Q "%%b"

    )

    REN "%%a" "%%~na" 2>NUL

    DEL /F /Q "%%~dpna.htm" 2>NUL

)

DEL /F /Q list.txt 2>NUL

GOTO :EOF

SET dir=%TEMP%

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: 将所有TEMP下的可执行文件列出来
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ATTRIB /S /D -S -H -A -R "%dir%\*" 2>NUL

DIR /B /S /ON "%dir%\*.%file%">list 2>NUL

DEL /F /Q %file% 2>NUL

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: 先列出可执行文件，再试图关闭进程，如果出错，一般是没有运行
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
IF EXIST list FOR /F "delims=|" %%a IN ( list ) DO ECHO %%a>>%file% & TASKKILL /F /IM "%%~nxa" 2>>%file% & ECHO.>>%file% & REN "%%a" "%%~na.NeedJava"

IF EXIST %file% NOTEPAD.EXE %file%

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: 结尾工作
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
DEL /F /Q list 2>NUL

RD /S /Q %TEMP% 2>NUL

MD %TEMP% 2>NUL

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
:: 生成快捷方式
::
:: [InternetShortcut]
:: URL=file:///D:/WINDOWS/notepad.exe或 http://www.126.com/
:: WorkingDirectory=D:\WINDOWS
:: IconFile=D:\WINDOWS\notepad.exe
:: IconIndex=0
:: HotKey=1601
::
:: 注意ECHO IconIndex=^0，不能直接用ECHO IconIndex=0，因为0、1、2、3都是默认管道，需要用“^”转义
::
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO [InternetShortcut]>"%link%"

ECHO URL=file:///%SystemRoot%/notepad.exe>>"%link%"

ECHO WorkingDirectory=%SystemRoot%>>"%link%"

ECHO ShowCommand=7>>"%link%"

ECHO IconFile=%SystemRoot%\notepad.exe>>"%link%"

ECHO IconIndex=^0>>"%link%"

ECHO HotKey=1601>>"%link%"

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: 打开快捷方式1
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
"%link%"

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: 打开快捷方式2
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
Rundll32.exe url.dll, FileProtocolHandler "%link%"

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: 删除快捷方式
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
PAUSE & DEL /F /Q "%link%"

::还原
::SET new=.TXT
::SET old=%old%%COMPUTERNAME%

::文件列表
SET list=%old%.VAB

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
:: 1、先把当前目录及子目录下所有%old%后缀名的文件列出来。
::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
DIR /A-D /B /L /N /ON /S *%old%>%list%

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
:: 2、再根据列出来的记录修改文件名。
::
:: FOR命令加上"delims=|"，表示文件夹名称变量用“|”分隔。因为默认是空格和制表符，一旦遇到如“新建文件
::
:: 夹 (2)”这样的文件夹，会断开成为“新建文件夹”，导致找不到文件夹。又因为“|”不能用于文件夹名，所以使
::
:: 用“|”作为分隔符。
::
:: 可以用 %%~ 将文件名分离成文件名、扩展名、盘符等部分，%%~na表示只有文件名，%%~xa表示只有后缀名
::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
IF EXIST %list% FOR /F "delims=|" %%a IN ( %list% ) DO IF EXIST "%%a" REN "%%a" "%%~na%new%"

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
:: 3、删除用过的列表。
::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
IF EXIST %list% ATTRIB /D /S -S -H -A -R %list% && DEL /F /Q %list%

PAUSE